mirror of
https://github.com/c-cube/tiny_httpd.git
synced 2025-12-06 11:15:35 -05:00
62 lines
2.4 KiB
OCaml
62 lines
2.4 KiB
OCaml
|
|
module S = Tiny_httpd
|
|
|
|
let () =
|
|
let port_ = ref 8080 in
|
|
let j = ref 32 in
|
|
Arg.parse (Arg.align [
|
|
"--port", Arg.Set_int port_, " set port";
|
|
"-p", Arg.Set_int port_, " set port";
|
|
"--debug", Arg.Unit (fun () -> S._enable_debug true), " enable debug";
|
|
"-j", Arg.Set_int j, " maximum number of connections";
|
|
]) (fun _ -> raise (Arg.Bad "")) "echo [option]*";
|
|
let server = S.create ~port:!port_ ~max_connections:!j () in
|
|
Tiny_httpd_camlzip.setup server;
|
|
(* say hello *)
|
|
S.add_path_handler ~meth:`GET server
|
|
"/hello/%s@/" (fun name _req -> S.Response.make_string (Ok ("hello " ^name ^"!\n")));
|
|
S.add_path_handler ~meth:`GET server
|
|
"/zcat/%s" (fun path _req ->
|
|
let path = match Tiny_httpd_util.percent_decode path with
|
|
| Some s -> s
|
|
| None -> S.Response.fail_raise ~code:404 "invalid path %S" path
|
|
in
|
|
let ic = open_in path in
|
|
let str = S.Byte_stream.of_chan ic in
|
|
let mime_type =
|
|
try
|
|
let p = Unix.open_process_in (Printf.sprintf "file -i -b %S" path) in
|
|
try
|
|
let s = ["Content-Type", String.trim (input_line p)] in
|
|
ignore @@ Unix.close_process_in p;
|
|
s
|
|
with _ -> ignore @@ Unix.close_process_in p; []
|
|
with _ -> []
|
|
in
|
|
S.Response.make_stream ~headers:mime_type (Ok str)
|
|
);
|
|
(* echo request *)
|
|
S.add_path_handler server
|
|
"/echo" (fun req ->
|
|
let q =
|
|
S.Request.query req |> List.map (fun (k,v) -> Printf.sprintf "%S = %S" k v)
|
|
|> String.concat ";"
|
|
in
|
|
S.Response.make_string
|
|
(Ok (Format.asprintf "echo:@ %a@ (query: %s)@." S.Request.pp req q)));
|
|
S.add_path_handler_stream ~meth:`PUT server
|
|
"/upload/%s" (fun path req ->
|
|
S._debug (fun k->k "start upload %S, headers:\n%s\n\n%!" path
|
|
(Format.asprintf "%a" S.Headers.pp (S.Request.headers req)));
|
|
try
|
|
let oc = open_out @@ "/tmp/" ^ path in
|
|
S.Byte_stream.to_chan oc req.S.Request.body;
|
|
flush oc;
|
|
S.Response.make_string (Ok "uploaded file")
|
|
with e ->
|
|
S.Response.fail ~code:500 "couldn't upload file: %s" (Printexc.to_string e)
|
|
);
|
|
Printf.printf "listening on http://%s:%d\n%!" (S.addr server) (S.port server);
|
|
match S.run server with
|
|
| Ok () -> ()
|
|
| Error e -> raise e
|